;>>> DIMEN-MATCHER.GXM
;>>> A repetitive macro that modifies the settings of an existing dimension
;>>> matching it with that of another existing dimension. 
;>>> Written by: Vincent Ferrara 2005 
;*******************************************************
;>>> Description:
;>>> First select your source dimension you wish to match other dimensions with. 
;>>> Then select the dimensions to change. Pressing [Enter] will allow give you the full Selection command. 
;>>> Only dimension settings are matched. The dimention  string remains unchanged.
;>>> This macro only works with GCP4 and above.
;
/MSP,++,/XMD,++,MO;
/VLC;
AL,??,/VIN,1,$VAL,AL,++;
SY,??,/VIN,2,$VAL,SY,++;
/SYS,C,V,/VST,1,$STR;
/STR,S,$S(1),1,1,/VIN,1,$STR;
/IF,$S(1)[LT]4,/GTO,VER-3;
;
.SOURCE;
/PMT,1,'Pick Source Dimension for Matching.>',#;
/PMT,2,;
/PMT,3,'[Esc] to cancel',#;
/CEL,F,D,!,A,!,O,@,!; 
/IF,$DERR[EQ]-2,/GTO,EXIT;
/IF,$VAL[EQ]0,/BEEP,/GTO,SOURCE;  
/EEX,1,P,3,A,/VPT,1,$PNTX,$PNTY;
;
.PICK;
/PMT,1,'Pick Dimensions to match with source dimension ',#;
/PMT,2,'[Enter] for Selection command',#;
/PMT,3,'[Esc] to cancel',#;
/CEL,F,D,!,A,!,O,@,!; 
/IF,$DERR[EQ]-2,/GTO,EXIT;
/IF,$DERR[EQ]-1,/GTO,SELECT; 
/IF,$VAL[EQ]0,/BEEP,/GTO,PICK;  
/GTO,CHANGE;
;
.SELECT;
/SEL,Select  Dimensions to match with source dimension;
/IF,$DERR[EQ]-2,/GTO,EXIT;
;
.CHANGE;
UG,L,!,MH,$X(1),$Y(1),!;
/GTO,PICK;
;
.VER-3;
/BEEP;
/PMT,1,'< SORRY > This macro only works with GCP4 and above ',#;
/PMT,2,'Please visit [www.generalcadd.com] and see the new features on offer ',#;
/PMT,3,'Press any key to continue',#,/CIN;
;
.EXIT;
/IF,$I(1)[EQ]0,AL,--;
/IF,$I(2)[EQ]0,SY,--;
/XMD,--,/MSP,--;