Vincent
Member
Registered: 06/25/02
Posts: 505
Loc: Newcastle, Australia
|
This macro will give you a preview of the font selection. That's what FS should have built in.
Anyway try it out especially pre GCP4 users and let me know if there are any bugs.
I will upload it if there are no problems with it.
Vincent
[EDIT] Added TS,X toggle to negate exploded text.
;>>> FONT-SELECT-PREVIEW.GXM
;>>> A font select with a preview
;>>> Written by: Vincent Ferrara 2006
;*******************************************************
;>>> Description:
;>>> The macro starts with a preview of the current font.
;>>> It is set on a loop so that clicking on a font name will give a preview.
;>>> Pressing [RET] will accept the last font previewed.
;>>> Pressing [ESC] will cancel and return you to your current font.
;
/MSP,++,/XMD,++,MO;
HI,--;
/VLC,;
AL,??,/VIN,10,$VAL,AL,++;
TS,X,??,!,/VIN,12,$VAL,TS,X,--,!;
/VIN,0,1023;
YC,!,/VIN,1,$VAL;
FS,!,/VST,0,$STR;
/VST,1,$S(0);
NV,SCREENSHOT,!;
/SYS,C,V,/VST,10,$STR;
/STR,S,$S(10),1,1,/VIN,11,$STR;
/IF,$I(11)[GE]4,/GET,WarningLockLayerMakeCurrentAttempt,/VIN,4,$VAL;
/IF,$I(11)[GE]4,/SET,WarningLockLayerMakeCurrentAttempt,0;
;
.EMPTY-LAYER;
/CEL,Y,$I(0),!,/VIN,2,$VAL;
/IF,$I(2)[NE]0,/VIN,0,$I(0)-1,/GTO,EMPTY-LAYER;
YC,$I(0);
YC,!,/VIN,3,$VAL;
/IF,$I(3)[EQ]$I(1),/VIN,0,$I(0)-1,/GTO,EMPTY-LAYER;
YC,$I(0);
/IF,$I(11)[GE]4,/SET,WarningLockLayerMakeCurrentAttempt,$I(4);
YH,1024,!;
/STR,C,ABCDEFGHIJKLMNOPQRSTUVWXYZ,%%CR%%,abcdefghijklmnopqstuvwxyz,%%CR%%,1234567890,%%CR%%,`~!@#$%^&*()_+-={}[]:"/;'?/<>/,.|\,#;
TL,0,0,$STR,#;
ZA;
SE,T,!,!;
;
.NEWFONT;
/PMT,1,'Font Select Preview',#;
/PMT,2,'Displayed Font is [',$S(1),],#;
/PMT,3,'[ESC] to Cancel: [RET] to Accept:_',#;
/XMD,--;
FS,~;
/IF,$DERR[EQ]-1,/GTO,END;
/IF,$DERR[EQ]-2,FS,$S(0),/GTO,END;
/VST,1,$STR;
/XMD,++;
TG,L,!,TF,$S(1),!;
ZA;
/GTO,NEWFONT;
;
.END;
ER,Y,$I(0),!,!;
YD,1024,!;
YC,$I(1);
ZV,SCREENSHOT;
NX,SCREENSHOT,#;
HI,++;
/IF,$I(10)[EQ]0,AL,--;
/IF,$I(12)[EQ]1,TS,X,++,!;
/MSP,--,/XMD,--,PU;
|
