;>>> TEXT-MATCHER.GXM
;>>> A repetitive macro that modifies the settings of an existing text line
;>>> and matching it with that of another existing text line. 
;>>> Written by: Vincent Ferrara 2005 
;*******************************************************
;>>> Description:
;>>> First select your source text you wish to match other texts with. 
;>>> Then select the texts to change. Pressing [Enter] will allow you to Group Text first. 
;>>> Only text settings are matched. The text string remains unchanged.
;>>>
;>>> History:
;>>> Revision A (05/11/05)
;>>> Code revision for GCP4 and maintaining legacy with earlier versions of GCP.
;
/MSP,++,/XMD,++,MO;
/VLC;
AL,??,/VIN,1,$VAL,AL,++;
SY,??,/VIN,2,$VAL,SY,++;
/SYS,C,V,/VST,1,$STR;
/STR,S,$S(1),1,1,/VIN,1,$STR;
;
.SOURCE;
/PMT,1,'Pick Source Text for Matching.>',#;
/PMT,2,;
/PMT,3,'[Esc] to cancel',#;
/CEL,F,T,!,A,!,O,@,!; 
/IF,$DERR[EQ]-2,/GTO,EXIT;
/IF,$VAL[EQ]0,/BEEP,/GTO,SOURCE;  
/EEX,1,P,1,A,/VPT,1,$PNTX,$PNTY;
;
.PICK;
/PMT,1,'Pick Text Lines to match with source text ',#;
/PMT,2,'[Enter] to Group Text first',#;
/PMT,3,'[Esc] to cancel',#;
/CEL,F,T,!,A,!,O,@,!; 
/IF,$DERR[EQ]-2,/GTO,EXIT;
/IF,$DERR[EQ]-1,/GTO,GROUP; 
/IF,$VAL[EQ]0,/BEEP,/GTO,PICK;  
;
.EXTRACT;
/CEL,L,!; 
/EEX,1,P,1,A,/VPT,2,$PNTX,$PNTY;
/EEX,1,V,8,A,/VST,2,$STR; 
/GTO,CHANGE;
;
.GROUP;
/SEL,Group Text;
/IF,$DERR[EQ]-2,/GTO,EXIT;
/PMT,1,'Pick Text Reference Point representing the start of the Text Group ',#;
/PMT,2,;
/PMT,3,'[Esc] to cancel',#;
GT,L,!,@,!;
/IF,$DERR[EQ]-2,/GTO,EXIT;
/GTO,EXTRACT;
;
.CHANGE;
/IF,$S(1)[LT]4,/GTO,VER-3;
TG,L,!,MH,$X(1),$Y(1),!;
/GTO,PICK;
.VER-3;
ER,L,!;
TA,$X(1),$Y(1),$S(2),#;
/CEL,T,!; 
/EEX,1,P,1,A,/VPT,3,$PNTX,$PNTY;
MV,T,!,$X(3),$Y(3),$X(2),$Y(2);
/GTO,PICK;
;
.EXIT;
/IF,$I(1)[EQ]0,AL,--;
/IF,$I(2)[EQ]0,SY,--;
/XMD,--,/MSP,--;