;>>> TEXT-FONT-CHANGE.GXM
;>>> Changes the font of Text Lines of one size only. 
;>>> Written by Vincent Ferrara 2005 
;**************************************************
;>>> Description:
;>>> Firstly select a text of a certain size you whish to change the font.
;>>> Secondly select the required font. 
;>>> Thirdly select the text you whish the font change to apply to.
;>>> This macro will filter out the text of that size and only the font will be changed. 
;
/MSP,++,/XMD,++,MO; 
/VLC,;
TZ,!,/VRL,0,$VAL;
FS,!,/VST,0,$STR;
;
.SOURCE;
/PMT,1,'Text Font Change',#;
/PMT,2,'Click Text of a certain size you whish to change the font',#; 
/CEL,F,T,!,A,!,@,!;
/IF,$DERR[EQ]-2,/GTO,EXIT; 
/EEX,1,V,2,A,/VRL,1,$STR;  
/EEX,1,V,6,A,/VST,1,$STR; 
/DEL;
;
.NEWFONT;
/PMT,1,'Text Font Change',#;
/PMT,2,'Select new font',#; 
/XMD,--,FS,~,/VST,2,$STR,/XMD,++;
/IF,$DERR[EQ]-2,/GTO,EXIT; 
;
.SELECT;
/SEL,Select Text Lines for new font to apply to..; 
/IF,$VAL[EQ]-2,/GTO,EXIT; 
/CEL,F,T,!,A,!,L,!; 
/VIN,0,$VAL; 
/VIN,1,$I(0)+1; 
;
.LOOP; 
/VIN,1,$I(1)-1; 
/IF,$I(1)[EQ]0,/GTO,EXIT; 
/EEX,$I(1),V,2,A,/VRL,2,$STR; 
/IF,$R(2)[EQ]$R(1),/GTO,CHANGEFONT;
/GTO,LOOP; 
;
.CHANGEFONT;
/EEX,$I(1),P,1,A,/VPT,1,$PNTX,$PNTY; 
/EEX,$I(1),V,6,A,/VST,3,$STR; 
/IF,$S(3)[EQ]$S(1),TG,O,$X(1),$Y(1),!,TF,$S(2),!;
/IF,$I(1)[GT]$I(0),/GTO,EXIT; 
/GTO,LOOP; 
;
.EXIT; 
TZ,$R(0),!,!;
FS,$S(0),!,!;
/MSP,--,/XMD,--,PU;